eldritch horrorsandjade
b0d7a81613
clangd broke because it can't look through symlinks. compile_commands manipulation does not fix it, clangd configuration does not fix it, a vfs overlay does not fix it, and while a combination of those can fix it with a bind mount in place that's just too cursed to even consider clangd bug: https://github.com/llvm/llvm-project/issues/116877 Change-Id: I8e3e8489548eb3a7aa65ac9d12a5ec8abf814aec
73 lines
2.1 KiB
Nix
73 lines
2.1 KiB
Nix
lockFileStr: rootSrc: rootSubdir:
|
|
|
|
let
|
|
|
|
lockFile = builtins.fromJSON lockFileStr;
|
|
|
|
allNodes = builtins.mapAttrs (
|
|
key: node:
|
|
let
|
|
|
|
sourceInfo =
|
|
if key == lockFile.root then
|
|
rootSrc
|
|
else
|
|
fetchTree (node.info or { } // removeAttrs node.locked [ "dir" ]);
|
|
|
|
subdir = if key == lockFile.root then rootSubdir else node.locked.dir or "";
|
|
|
|
outPath = sourceInfo + ((if subdir == "" then "" else "/") + subdir);
|
|
|
|
flake = import (outPath + "/flake.nix");
|
|
|
|
inputs = builtins.mapAttrs (inputName: inputSpec: allNodes.${resolveInput inputSpec}) (
|
|
node.inputs or { }
|
|
);
|
|
|
|
# Resolve a input spec into a node name. An input spec is
|
|
# either a node name, or a 'follows' path from the root
|
|
# node.
|
|
resolveInput =
|
|
inputSpec: if builtins.isList inputSpec then getInputByPath lockFile.root inputSpec else inputSpec;
|
|
|
|
# Follow an input path (e.g. ["dwarffs" "nixpkgs"]) from the
|
|
# root node, returning the final node.
|
|
getInputByPath =
|
|
nodeName: path:
|
|
if path == [ ] then
|
|
nodeName
|
|
else
|
|
getInputByPath
|
|
# Since this could be a 'follows' input, call resolveInput.
|
|
(resolveInput lockFile.nodes.${nodeName}.inputs.${builtins.head path})
|
|
(builtins.tail path);
|
|
|
|
outputs = flake.outputs (inputs // { self = result; });
|
|
|
|
result =
|
|
outputs
|
|
# We add the sourceInfo attribute for its metadata, as they are
|
|
# relevant metadata for the flake. However, the outPath of the
|
|
# sourceInfo does not necessarily match the outPath of the flake,
|
|
# as the flake may be in a subdirectory of a source.
|
|
# This is shadowed in the next //
|
|
// sourceInfo
|
|
// {
|
|
# This shadows the sourceInfo.outPath
|
|
inherit outPath;
|
|
|
|
inherit inputs;
|
|
inherit outputs;
|
|
inherit sourceInfo;
|
|
_type = "flake";
|
|
};
|
|
in
|
|
if node.flake or true then
|
|
assert builtins.isFunction flake.outputs;
|
|
result
|
|
else
|
|
sourceInfo
|
|
) lockFile.nodes;
|
|
in
|
|
allNodes.${lockFile.root}
|